THEMA:

#include <Wire.h>
 
byte MS5611Address = false;
int64_t MS5611C[7];
unsigned long MS5611TimeConversion; // us
 
void MS5611Transmit(int command) {
  if (!MS5611Address) return;
  Wire.beginTransmission(MS5611Address);
  Wire.write(command);
  Wire.endTransmission();
}
 
int64_t MS5611Receive(int command, int bytes) {
  if (!MS5611Address) return;
  MS5611Transmit(command);
  Wire.requestFrom(MS5611Address, bytes);
  int64_t response = 0;
  for (int i = 0; i < bytes; i++) response = (response << 8) | Wire.read();
  return response;
}
 
void MS5611Reset() {
  MS5611Transmit(0x1e);
  delayMicroseconds(3000);
}
 
void MS5611ConvertD1() { // pressure conversion
  MS5611Transmit(0x48); // OSR=4096
  MS5611TimeConversion = micros() + 9040L;
}
 
void MS5611ConvertD2() { // temperature conversion
  MS5611Transmit(0x50); // OSR=256
  MS5611TimeConversion = micros() + 600L; 
}
 
int64_t MS5611ReadADC() {
  while (long(MS5611TimeConversion - micros()) > 0); // wait for conversion to be done
  return MS5611Receive(0x00, 3);
}
 
int64_t MS5611ReadCalibration(int index) {
  return MS5611Receive(0xa0 + index * 2, 2);
}
 
void MS5611Init() {
  Wire.begin(); // start communication with MS5611 as master
  MS5611Address = 0x76;
  Wire.beginTransmission(MS5611Address);
  if (Wire.endTransmission() != 0) {
    MS5611Address = 0x77;
    Wire.beginTransmission(MS5611Address);
    if (Wire.endTransmission() != 0) {
      MS5611Address = false;
      return;
    }
  }
  MS5611Reset(); // reset MS5611
  for (int i = 1; i <= 6; i++) MS5611C[i] = MS5611ReadCalibration(i); // read calibration coefficients
  MS5611ConvertD1(); // start the pressure conversion
}
 
void MS5611GetD1() {
  MS5611C[0] = MS5611ReadADC(); // read the converted pressure started last time
  MS5611ConvertD2(); // start the temperature conversion to be ready to read next time
}
 
float MS5611GetD2() {
  int64_t D2 = MS5611ReadADC(); // read the converted temperature started last time
  MS5611ConvertD1(); // start the pressure conversion to be ready to read next time
 
  int64_t dT = D2 - (MS5611C[5] << 8);
  int64_t TEMP = ((dT * MS5611C[6]) >> 23);
  int64_t OFF = (MS5611C[2] << 16) + ((MS5611C[4] * dT) >> 7);
  int64_t SENS = (MS5611C[1] << 15) + ((MS5611C[3] * dT) >> 8);
  if (TEMP < 0) {
    OFF -= (5 * TEMP * TEMP) >> 1;
    SENS -= (5 * TEMP * TEMP) >> 2;
    //TEMP -= (dT * dT) >> 31;
  }
  //temperature = 0.01 * (TEMP + 29315); // Kelvin
  return (((MS5611C[0] * SENS) >> 21) - OFF) >> 15; // Pa
}